STEP 1 - Define a structures for the BAPI

In this step a structures for the parameters and tables of the function module used for the BAPI are defined.

Use Data type -> Structure

Define the following structures:

ZBAPI_ORDER_STATUS_IMPORT which contains the following fields:

• ORDERID Order number (Keyfield)
• SPRAS Language
• ExcludeInactive - Checkbox - Exclude inactive status

ZBAPISTAT:

OBJNR like JEST-OBJNR

• STAT like JEST-STAT
• INACT like JEST-INACT
• TXT04 like TJ02T-TXT04
• TXT30 likeTJ02T-TXT30

Important note:

You will have to define a structure for every parameter in the BAPI. You cannot use the same structures used in existing applications because BAPI structures are frozen when BAPIs are released and then there are restrictions on changing them.

ZBAPI_ORDER_STATUS_IMPORT

ZBAPISTAT

STEP 2 - Write Function Module

Important notes:

• Each BAPI must have its own function group.
• Under the attrbutes tab remember to select Processing Type Remote Enabled module, otherwise the function module cannot be invoked via RFC and used as a BAPI
• Import/Export parameters can only be BY VALUE for an RFC enabled function module
• We are only creating one BAPI in this example, but you can create related BAPIs in the same function pool, so they will be able to share global data.

Attributes

Import Parameters

Export Parameters

Tables

Code

Notes:

• The subroutine SET_RETURN_MESSAGE is a standard routine used for BAPIs that use the BAPIRETURN structure

• In form Z_BAPI_GET_ORDER_SYSTEM_STATUS there is a test IF 1 = 2. If the test is true a mesage is displayed. The condition will obviously never be true, and we will never want to display a message in a BAPI. The reason why it is included is, that it create a reference for the message, so that the WHERE USED funstionallity can be used for the message. This is the SAP standard way to handle it, copied from the Company Code GetList BAPI.

INCLUDE LZBAPISTATUSUXX

*****************************************************************
*   THIS FILE IS GENERATED BY THE FUNCTION LIBRARY.             *
*   NEVER CHANGE IT MANUALLY, PLEASE!                           *
*****************************************************************
INCLUDE LZBAPISTATUSU02.
                    "Z_BAPI_GET_ORDER_SYSTEM_STATUS

INCLUDE LZBAPISTATUSTOP - Global data

FUNCTION-POOL ZBAPISTATUS.                  "MESSAGE-ID Z3
Types:
  begin of Type_tj02t,
    istat  like tj02t-istat,
    txt04  like tj02t-txt04,
    txt30  like tj02t-txt30,
  end of type_tj02t.



DATA:
* Declarations for TABLE parameter
  T_BAPISTAT like ZBAPISTAT occurs 0,
  G_BAPISTAT like ZBAPISTAT,
* Table for object texts
  t_tj02t    type type_tj02t occurs 0,
  g_tj02t    type type_tj02t.

* Structure for return messages
DATA:
  BEGIN OF MESSAGE,
    MSGTY LIKE SY-MSGTY,
    MSGID LIKE SY-MSGID,
    MSGNO LIKE SY-MSGNO,
    MSGV1 LIKE SY-MSGV1,
    MSGV2 LIKE SY-MSGV2,
    MSGV3 LIKE SY-MSGV3,
    MSGV4 LIKE SY-MSGV4,
  END OF MESSAGE.

INCLUDE LZBAPISTATUSF01 - Subroutines

***INCLUDE LZBAPISTATUSF01 .
*----------------------------------------------------------------------*

*&---------------------------------------------------------------------*
*&      Form  SET_RETURN_MESSAGE
*&---------------------------------------------------------------------*
* This routine is used for setting the BAPI return message.
*
* The routine is a standard routine for BAPIs that handles the message
* structure for the BAPIRETURN structure. It has been copied from the
* BAPI Company Code Getlist
*----------------------------------------------------------------------*
*      -->P_MESSAGE  text
*      <--P_RETURN  text
*----------------------------------------------------------------------*
form SET_RETURN_MESSAGE USING    VALUE(P_MESSAGE)   LIKE MESSAGE
                        CHANGING P_RETURN  LIKE BAPIRETURN.

  CHECK NOT MESSAGE IS INITIAL.

  CALL FUNCTION 'BALW_BAPIRETURN_GET'
       EXPORTING
            TYPE       = P_MESSAGE-MSGTY
            CL         = P_MESSAGE-MSGID
            NUMBER     = P_MESSAGE-MSGNO
            PAR1       = P_MESSAGE-MSGV1
            PAR2       = P_MESSAGE-MSGV2
            PAR3       = P_MESSAGE-MSGV3
            PAR4       = P_MESSAGE-MSGV4
*          LOG_NO     = ' '
*          LOG_MSG_NO = ' '
       IMPORTING
            BAPIRETURN = P_RETURN
       EXCEPTIONS
            OTHERS     = 1.


endform.                    " SET_RETURN_MESSAGE

FUNCTION Z_BAPI_GET_ORDER_STATUS

FUNCTION z_bapi_get_order_system_status.
*"----------------------------------------------------------------------
*"*"Local interface:
*"  IMPORTING
*"     VALUE(I_AUFNR) TYPE  AUFNR
*"     VALUE(I_SPRAS) TYPE  SPRAS DEFAULT SY-LANGU
*"     VALUE(I_EXCLUDEINACTIVE) TYPE  CHAR1 OPTIONAL
*"  EXPORTING
*"     VALUE(RETURN) TYPE  BAPIRETURN
*"  TABLES
*"      T_BAPISTAT STRUCTURE  ZBAPISTAT
*"----------------------------------------------------------------------
**
*"Local interface:
*"  IMPORTING
*"     VALUE(I_AUFNR) TYPE  AUFNR
*"     VALUE(I_SPRAS) TYPE  SPRAS DEFAULT SY-LANGU
*"     VALUE(I_EXCLUDEINACTIVE) TYPE  CHAR1 OPTIONAL
*"  EXPORTING
*"     VALUE(RETURN) TYPE  BAPIRET2
*"  TABLES
*"      T_BAPISTAT STRUCTURE  ZBAPISTAT
*"----------------------------------------------------------------------
  DATA:
   l_aufnr LIKE afko-aufnr,
   l_objnr LIKE jest-objnr.


********************************************
* Check if order exists
********************************************
  SELECT SINGLE aufnr
    FROM afko
    INTO  l_aufnr
    WHERE aufnr = BAPI_ORDER_STATUS_IMPORT-orderid.

  IF sy-subrc NE 0.
    CLEAR message.
    message-msgty = 'E'.
    message-msgid = 'Z3'.
    message-msgno = '000'.
    message-msgv1 = BAPI_ORDER_STATUS_IMPORT-orderid.
    PERFORM set_return_message USING    message
                               CHANGING return.
    IF 1 = 2.
*     The only reason to include this statement, that will obviously
*     never execute, is that it will create a referecence so that you
*     can find out where a particular message is being used. This
*     functionality is used by the BAPIs programmed by SAP
      MESSAGE e000(z3).
    ENDIF.
  ENDIF.
  CHECK return IS INITIAL.

********************************************
* Read order status
********************************************
  CONCATENATE 'OR' BAPI_ORDER_STATUS_IMPORT-orderid INTO l_objnr.

  IF BAPI_ORDER_STATUS_IMPORT-i_excludeinactive = 'X'.
    SELECT objnr stat inact
      FROM  jest
      INTO  TABLE t_bapistat
      WHERE objnr = l_objnr AND
            inact <> 'X'.
  ELSE.
    SELECT objnr stat inact
      FROM  jest
      INTO  TABLE t_bapistat
      WHERE objnr = l_objnr.

  ENDIF.
  IF sy-subrc <> 0.
*   No object status found
    CLEAR message.
    message-msgty = 'E'.
    message-msgid = 'Z3'.
    message-msgno = '001'.
    message-msgv1 = BAPI_ORDER_STATUS_IMPORT-orderid.
    PERFORM set_return_message USING    message
                               CHANGING return.
    IF 1 = 2.
      MESSAGE e001(z3).
    ENDIF.
  ENDIF.
  CHECK return IS INITIAL.


********************************************
* Read order status texts
********************************************
  SELECT istat txt04 txt30
    FROM tj02t
    INTO TABLE t_tj02t
    FOR ALL ENTRIES IN t_bapistat
    WHERE istat = t_bapistat-stat AND
          spras = BAPI_ORDER_STATUS_IMPORT-i_spras.

  SORT t_tj02t BY istat.

  LOOP AT t_bapistat INTO g_bapistat.
    READ TABLE t_tj02t
      WITH KEY istat = g_bapistat-stat BINARY SEARCH
      INTO g_tj02t.
    IF sy-subrc = 0.
      MOVE:
        g_tj02t-txt04 TO g_bapistat-txt04,
        g_tj02t-txt30 TO g_bapistat-txt30.
      MODIFY t_bapistat FROM g_bapistat TRANSPORTING txt04 txt30.
    ENDIF.


  ENDLOOP.


ENDFUNCTION.

STEP 3 - Create the API Method Using the BAPI WIZARD

The BAPI wizard is used toTo expose the remote function module as a BAPI. The wizard will generate some additional code, so the function module is a valid method of the BOR. This allows the BAPi to be called as a workflow method in addition to be called by an outside program.

Note: Each functionmodule corresponds to a method in the BOR

Go to the Busines Object Builder SWO1.

You can either create the new Object type as a subtype of an existing business object or create a new business object from scratch. In this example it would be obvious to create the Object type as a subtype of BUS2005 Production order. However, to illustrate how to create a new Object type from scratch, we will do this.

In the Object/Interface type field write the name of the new Business Object: ZORDERSTAT. Press enter and fill in the additional fields necessary to create the object type.

Supertype: Not relevant because we are creating our object from scratch

Program. This is the name of the program where the wizard generates code for the Object type, NOT the function module we craeted earlier. The program name must not be the name of an existinbg program.

Press enter and create the new business object. Note that when you create the business object a standard interface, an attribute ObjectType and the methods ExistenceCheck and Display are automatically generated. These cannot be changed !

The next step is to add the Z_BAPI_GET_ORDER_STATUS method to the business object. Select Utillities -> API methods -> Add method and write the name of the functionmodule in the dialogbox. Next the dialogbox show below will be shown. This is the start screen of the BAPI wizard. Proceed with wizard by pressing the button.

After you have finished the wizard, tyou will notice that the ZGetOrderStatus has been added to the business object:

You can doubleclick on the method to see its properties. To use the business object you must change the Object type status to Implemented. Use menu Edit->Change releases status->Object type->To implemented. No you can test thge object (Press F8).

Note that the BAPI wizard has added a wrapper class for the function module so it can be sued as method in the business object. Choose menu Goto->Program to display the program:

*****           Implementation of object type ZORDERSTAT           *****
INCLUDE